Spawnpoint: Not CP OR Flag

(LaggingTom) #1

Well, in my map, you construct a little stone thingy, and supposedly, you should spawn there. But you don’t. All the targetnames/scriptnames are correct, but I get a setautospawn error when I run it.

center
{
	spawn
	{
		wait 200
		trigger self startup
		constructible_class 		1
		constructible_health 		1500
		constructible_chargebarreq	.2
	}
	
	buildstart final
	{
		wm_announce "The Allies are constructing the Obelisk!"
	}

	built final
	{
		trigger game_manager built_counter
		wm_announce "The Obelisk has been constructed!"
		setstate construction_materials invisible
		setstate extra default
		setstate center default
		setstate center_wojb default
		setautospawn "Obelisk Spawn" 1
		alertentity center_wobj
	}

	death
	{
		trigger game_manager death_counter
		wm_announce "The Obelisk has been destroyed!"
		setstate construction_materials default
		setstate extra invisible
		setstate center invisible
		setautospawn "Allies Spawn" 1
		setstate center_wobj invisible
	}
	
	decayed final
	{
		setstate center invisible
	}

	trigger startup
	{
		setstate center invisible
		setstate construction_materials default
		setstate extra invisible
		setstate center_wobj invisible
	}
}
(Chruker) #2

Which setautospawn error: ‘setautospawn, couldn’t find target’ or one of the ‘setautospawn must have a target xxxx’

(LaggingTom) #3

setautospawn, couldn’t find target

(Java.Lang) #4

Perhaps you have mispelled the targetname. I’m not sure, but those strings may be case-sensitive. Double, triple check your spelling.

(Chruker) #5

Perhaps you can list the relevant entities and their keys

(LaggingTom) #6

I’m sure, but here ya go:



(LaggingTom) #7

I added a target key with a value of “center_wobj” to the center objective, and a targetname value of “center_wobj” to the blue spawn it controls.

(Chruker) #8

I’m blank about this issue, mainly because I haven’t made many spawn points yet. However I just twisted my brain, and remembered that in the Vengeance map, axis can construct a command post and once its constructed they spawn there. The notes in the script said that Mean Mr. Mustard made that part of it, so perhaps if he could answer this.

(LaggingTom) #9

I’ve checkout out many command post scripts, and I’ve found nothing of use. The only differences I can find are that there are some “_radio” extension tags, a few models, and sounds. All of which are un-needed.

(Mean Mr. Mustard) #10

It looks like everything is correct :???: …at least with the stuff you provided.

Could you copy the spawn entities into a box map (include your scripting for them) and post it or PM a link to me? I’ll take a look at it and start debugging it.

(LaggingTom) #11

http://ee.domaindlx.com/LaggingTom/maze.map

Mind you, I don’t have unlimited bandwith. I think about a gig a day, though, so we should be set.

(LaggingTom) #12

After some major work and much help from Mean Mr. Mustard, it’s working. The center spawn is fine.
The final script:

center
{
	spawn
	{
		wait 200
		trigger self startup
		constructible_class 		1
		constructible_health 		1500
		constructible_chargebarreq	.2
	}
	
	buildstart final
	{
		wm_announce "The Allies are constructing the Obelisk!"
	}

	built final
	{
		trigger game_manager built_counter
		wm_announce "The Obelisk has been constructed!"
		setstate construction_materials invisible
		setstate extra default
		setstate center default
		setstate construction_toi invisible
		setstate center_spawn_wobj default
		setstate center_spawn default
		setautospawn "Obelisk Spawn" 1
		alertentity center_spawn
	}

	death
	{
		trigger game_manager death_counter
		wm_announce "The Obelisk has been destroyed!"
		setstate construction_materials default
		setstate extra invisible
		setstate center invisible
		setautospawn "Allies Spawn" 1
		setstate center_spawn_wobj invisible
		setstate center_spawn invisible
		setstate construction_toi default
	}
	
	decayed final
	{
		setstate center invisible
	}

	trigger startup
	{
		setstate center invisible
		setstate construction_materials default
		setstate extra invisible
		setstate construction_toi default
	}
}

center_spawn
{
	spawn
	{
		wait 200
		setstate center_spawn invisible
		setstate center_spawn_wobj invisible
	}
}
(Chruker) #13

Good to hear.

What was the problem? Missing entities? Missing keys? Some bug that needed a work-around? All of the above?

(Mean Mr. Mustard) #14

It was a simple solution, but one that took a while to track. The ‘setautospawn’ in game_manager was occurring before the team_WOLF_objective spawned! So we added a ‘wait 2000’ in game_manager right before the ‘setautospawn’ commands and presto…problem solved

(LaggingTom) #15

And some spelling checks, too. Also, the spawns and entities were script/target named the same in some places. Thanks again Not-Too-Mean Mr. Mustard! (I apologize for the awful joke :stuck_out_tongue: )