spawn points defaulting when objective is destroyed

(blushing_bride) #1

im trying to get a spawn point to switch to allied after the allies blow up a wall. i want it to be exactly like in oasis. the old city flag (capturable spawn) works fine except when the allies blow up the wall it just stays the same. When the wall blows up the spanw is meant to turn into an allied only spawn but it does not. im not very good at scripting so i just cut and paste bits from oasis and added it to what i already have. im sure it must have something to do with accum values but as i have no idea of how accum stuff works then im lost. here is the script that i’ve cobbled together. can someone help me understand what im doing wrong (beside being too stupid to understand scripting :???: ) thanks in advance

game_manager 
{ 
spawn 
{ 
wait 50 
disablespeaker wp1_sound // water pump 1 

// *----------------------------------- vo ------------------------------------------* 
wm_teamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_teamvoiceannounce 1 "oasis_allies_pump_repair" 

wm_addteamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_addteamvoiceannounce 1 "oasis_allies_pump_repair" 
// *---------------------------------------------------------------------------------* 

wait 150

		setautospawn "Old City"			1
		setautospawn "Old City"			0
} 
} 

water_pump_1 
{ 
spawn 
{ 
wait 200 

constructible_class 2 // Dyno+Satchel 
trigger water_pump_1 setup 
} 

trigger setup 
{ 
setstate pump_materials_1 default 
setstate pump_materials_clip_1 default 
setstate pump_flag_1 default 
setstate pump1_p1 default 
setstate pump1_p2 invisible 
setstate water_pump_1_oldclip default 
} 

buildstart final 
{ 
setstate pump_materials_1 default 
setstate pump_materials_clip_1 default 
setstate pump_flag_1 default 
setstate pump1_p2 underconstruction 

} 

built final 
{ 
setstate pump_materials_1 invisible 
setstate pump_materials_clip_1 invisible 
setstate pump_flag_1 invisible 
setstate water_pump_1_oldclip invisible 
setstate pump1_p2 default 

enablespeaker wp1_sound 
 
wm_announce "Allies have built the Oasis Water Pump!" 
globalaccum 1 inc 1
trigger water move

// *----------------------------------- vo ------------------------------------------* 
wm_teamvoiceannounce 0 "oasis_axis_pump_disable" 
wm_teamvoiceannounce 0 "oasis_axis_caves_drain" 

wm_teamvoiceannounce 1 "oasis_allies_pump_repaired" 
wm_teamvoiceannounce 1 "oasis_allies_caves_drain" 

wm_removeteamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_removeteamvoiceannounce 1 "oasis_allies_pump_repair" 
// *---------------------------------------------------------------------------------* 
} 

death 
{ 
setstate pump_materials_1 default 
setstate pump_materials_clip_1 default 
setstate pump_flag_1 default 
setstate pump1_p2 invisible 
setstate pump_sound invisible 
setstate water_pump_1_oldclip default 

disablespeaker wp1_sound 

wm_announce "Axis have damaged the Oasis Water Pump!" 
globalaccum 1 inc -1
trigger water move

// *----------------------------------- vo ------------------------------------------* 
wm_addteamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_addteamvoiceannounce 1 "oasis_allies_pump_repair" 

wm_teamvoiceannounce 0 "oasis_axis_pump_disabled" 
wm_teamvoiceannounce 0 "oasis_axis_caves_flood" 

wm_teamvoiceannounce 1 "oasis_allies_pump_disabled" 
wm_teamvoiceannounce 1 "oasis_allies_caves_flood" 
// *---------------------------------------------------------------------------------* 

} 

decayed final 
{ 
setstate pump_materials_1 default 
setstate pump_materials_clip_1 default 
setstate pump_flag_1 default 
setstate pump1_p1 default 
setstate pump1_p2 invisible 
setstate water_pump_1_oldclip default 
} 
} 

pump1_p2 
{ 
spawn 
{ 
startanimation 0 40 20 nolerp 
} 
} 


//WATER PUMP 2
water_pump_2 
{ 
spawn 
{ 
wait 200 

constructible_class 2 // Dyno+Satchel 
trigger water_pump_2 setup 
} 

trigger setup 
{ 
setstate pump_materials_2 default 
setstate pump_materials_clip_2 default 
setstate pump_flag_2 default 
setstate pump2_p1 default 
setstate pump2_p2 invisible 
setstate water_pump_2_oldclip default 
} 

buildstart final 
{ 
setstate pump_materials_2 default 
setstate pump_materials_clip_2 default 
setstate pump_flag_2 default 
setstate pump2_p2 underconstruction 

} 

built final 
{ 
setstate pump_materials_2 invisible 
setstate pump_materials_clip_2 invisible 
setstate pump_flag_2 invisible 
setstate water_pump_2_oldclip invisible 
setstate pump2_p2 default 

enablespeaker wp2_sound 
 
wm_announce "Allies have built the Oasis Water Pump!" 
globalaccum 1 inc 1
trigger water move

// *----------------------------------- vo ------------------------------------------* 
wm_teamvoiceannounce 0 "oasis_axis_pump_disable" 
wm_teamvoiceannounce 0 "oasis_axis_caves_drain" 

wm_teamvoiceannounce 1 "oasis_allies_pump_repaired" 
wm_teamvoiceannounce 1 "oasis_allies_caves_drain" 

wm_removeteamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_removeteamvoiceannounce 1 "oasis_allies_pump_repair" 
// *---------------------------------------------------------------------------------* 
} 

death 
{ 
setstate pump_materials_2 default 
setstate pump_materials_clip_2 default 
setstate pump_flag_2 default 
setstate pump2_p2 invisible 
setstate pump_sound invisible 
setstate water_pump_2_oldclip default 

disablespeaker wp2_sound 

wm_announce "Axis have damaged the Oasis Water Pump!" 
globalaccum 1 inc -1
trigger water move

// *----------------------------------- vo ------------------------------------------* 
wm_addteamvoiceannounce 0 "oasis_axis_pump_stop" 
wm_addteamvoiceannounce 1 "oasis_allies_pump_repair" 

wm_teamvoiceannounce 0 "oasis_axis_pump_disabled" 
wm_teamvoiceannounce 0 "oasis_axis_caves_flood" 

wm_teamvoiceannounce 1 "oasis_allies_pump_disabled" 
wm_teamvoiceannounce 1 "oasis_allies_caves_flood" 
// *---------------------------------------------------------------------------------* 

} 

decayed final 
{ 
setstate pump_materials_2 default 
setstate pump_materials_clip_2 default 
setstate pump_flag_2 default 
setstate pump2_p1 default 
setstate pump2_p2 invisible 
setstate water_pump_2_oldclip default 
} 
} 

pump2_p2 
{ 
spawn 
{ 
startanimation 0 40 20 nolerp 
} 
} 

water 
{ 
spawn 
{ 
wait 200 
globalaccum 1 set 0 // upper position 
} 

trigger move 
{ 
globalaccum 1 trigger_if_equal 0 water pos_0 
globalaccum 1 trigger_if_equal 1 water pos_1 
globalaccum 1 trigger_if_equal 2 water pos_2 
} 

trigger pos_0 
{ 
gotomarker upperpos 25 wait
} 

trigger pos_1 
{ 
gotomarker middlepos 25 wait 
} 

trigger pos_2 
{ 
gotomarker lowerpos 25 wait
} 
}

oldcityflag
{
	spawn
	{
		accum 0 set 0	// Who has the flag: 0-Axis, 1-Allied
	}

	trigger axis_capture	// Flag has been touched by an Axis player
	{
		accum 0 abort_if_equal 0 // do Axis own flag?

		accum 0 set 0 // Axis own the pole
		wm_announce	"Axis reclaim the Old City!"

		// *----------------------------------- vo ------------------------------------------*
		wm_addteamvoiceannounce 0 "oasis_axis_city_defend"

		wm_addteamvoiceannounce 1 "oasis_allies_city_capture"

		wm_teamvoiceannounce 0 "oasis_axis_city_captured"

		wm_teamvoiceannounce 1 "oasis_allies_city_lost"

		wm_removeteamvoiceannounce 0 "oasis_axis_wall_defend"

		wm_removeteamvoiceannounce 1 "oasis_allies_wall_destroy"
		// *---------------------------------------------------------------------------------*

		wm_objective_status 		4 0 1
		wm_objective_status 		4 1 2

		alertentity old_city_wobj
	}

	trigger allied_capture	// Flag has been touched by an allied player
	{
		accum 0 abort_if_equal 1 // do Allies own flag?

		accum 0 set 1 // Allied own the flag
		wm_announce	"Allies capture the Old City!"

		// *----------------------------------- vo ------------------------------------------*
		wm_addteamvoiceannounce 0 "oasis_axis_wall_defend"

		wm_addteamvoiceannounce 1 "oasis_allies_wall_destroy"

		wm_teamvoiceannounce 0 "oasis_axis_city_lost"
		wm_teamvoiceannounce 0 "oasis_axis_wall_defend"

		wm_teamvoiceannounce 1 "oasis_allies_city_captured"
		wm_teamvoiceannounce 1 "oasis_allies_wall_destroy"

		wm_removeteamvoiceannounce 0 "oasis_axis_city_defend"

		wm_removeteamvoiceannounce 1 "oasis_allies_city_capture"
		// *---------------------------------------------------------------------------------*

		wm_objective_status 		4 0 2
		wm_objective_status 		4 1 1

		alertentity old_city_wobj
	}

	trigger check_obj
	{
		accum 0 abort_if_equal 1 // Do Allied own the flag?

		wm_objective_status 		4 0 2
		wm_objective_status 		4 1 1

	}

	trigger force_allied
	{
		accum 0 abort_if_equal 1 // Do Allied own the flag?

		alertentity old_city_wobj
		alertentity oldcityspawns
	}

	trigger kill
	{
		remove
	}
}

oldcitywall //Broken section of Old City wall
{
	spawn
	{
		wait 200

		constructible_class 3
	}

	death
	{
		trigger oldcityflag force_allied // Switch forward spawn to Allied ONLY

		trigger oldcityflag check_obj

		trigger oldcityflag kill

		wm_announce "Allies have breached the Old City wall"

		// *----------------------------------- vo ------------------------------------------*
		wm_addteamvoiceannounce 0 "oasis_axis_paks_defend"

		wm_addteamvoiceannounce 1 "oasis_allies_paks_destroy"

		wm_teamvoiceannounce 0 "oasis_axis_wall_destroyed"
		wm_teamvoiceannounce 0 "oasis_axis_paks_defend"

		wm_teamvoiceannounce 1 "oasis_allies_wall_destroyed"
		wm_teamvoiceannounce 1 "oasis_allies_paks_destroy"

		wm_removeteamvoiceannounce 0 "oasis_axis_wall_defend"
		wm_removeteamvoiceannounce 0 "oasis_axis_city_defend"

		wm_removeteamvoiceannounce 1 "oasis_allies_wall_destroy"
		wm_removeteamvoiceannounce 1 "oasis_allies_city_capture"
		// *---------------------------------------------------------------------------------*

		wm_objective_status 		3 0 2
		wm_objective_status 		3 1 1

		wm_set_main_objective	1 0
		wm_set_main_objective	1 1
	}
}
(StormShadow) #2

The script looks correct… maybe there is something wrong with your entities?

I had a similar problem, which was the result of me mislabelling my forward allied spawns.

Make sure your forward axis spawns are named oldcityspawns.

(blushing_bride) #3

thanks StormShadow, the problem was in the map not the script. i forgot to check the start active box in the other axis spawn and also i had not linked the the two dyno wall bits together.