map end

(Blockbuster) #1

hi there
i working on this map (see link in my sig for pics) and im making the objectives… axis need to destroy the bridge and allies need to destroy the flak cannon… i made them destructable with dynamite and all… works perfect… but i have a question: how to end the map when the allies did there objective or the axis did there objective first. please help i cant script :slight_smile: thnx in advance!!

(Blockbuster) #2

for the people who want to look at the simple script:


game_manager
{
	spawn
	{
		// Game rules
		wm_axis_respawntime	30
		wm_allied_respawntime	17
		wm_number_of_objectives 2
		wm_set_round_timelimit	30
	}
}

flak
{
	spawn
	{
		wait 200
		constructible_class 3
	}

	death
	{
		wm_announce "Allies have destroyed the flak cannon!"
	}
}

bridge
{
	spawn
	{
		wait 200
		constructible_class 3
	}

	death
	{
		wm_announce "axis have destroyed the bridge!"
	}
}
(*[SfS]*OpTeRoN) #3 
trigger checkgame
	{
		accum 1 abort_if_not_equal 1

		// Set the round winner:  0 == AXIS, 1 == ALLIED
		wm_setwinner 1

		// End the round
		wm_endround

That’s the script in RTCW, don’t know if it’s the same in ET.
If it works, tell me, so I can find out for my map. :drink:

(Blockbuster) #4

hmm i dont know :slight_smile: ill just wait for sock to the resq :wink:

:moo:

(Harty) #5

Im only a kinda noobish mapper, but did you check that when you made the entity in radiant or whatever that you put checked the box that triggered the death for a team when the object was destroyed?

harty

(sock) #6

The end game routine must be located in the game_manager routine. (well I think so, all the other scripts use game_manager) Trigger the relevent endgame routine depending on who has won the game. Use the death functions to call the the correct game_manager trigger.

Try this script:


game_manager
{
	spawn
	{
		// Game rules
		wm_axis_respawntime	30
		wm_allied_respawntime	17
		wm_number_of_objectives 2
		wm_set_round_timelimit	30
	}

	trigger axis_endgame
	{
		// Set the round winner:  0 == AXIS, 1 == ALLIED
		wm_setwinner 0
		wm_endround
	}
	trigger allied_endgame
	{
		// Set the round winner:  0 == AXIS, 1 == ALLIED
		wm_setwinner 1
		wm_endround
	}
}

flak
{
	spawn
	{
		wait 200
		constructible_class 3
	}

	death
	{
		wm_announce "Allies have destroyed the flak cannon!"
		trigger game_manager allied_endgame
	}
}

bridge
{
	spawn
	{
		wait 200
		constructible_class 3
	}

	death
	{
		wm_announce "axis have destroyed the bridge!"
		trigger game_manager axis_endgame
	}
}

Sock
:moo:

(Blockbuster) #7

THANK YOU BIG TIME SOCK! it works!! :beer: beer is on me (come get it here, while there cold)